TcxPageControl - The "List index out of bounds" exception is thrown when sequentially closing the first and then the second pages using the Close button of the navigator bar

Hello TOMAŽ,
Changing the ChangeActivePage method in the cxPC.pas file this way fixes the problem in VCL 12.2.4:

Delphi
procedure TcxPageControlProperties.ChangeActivePage(APage: TcxTabSheet);  

  procedure DoChangeActivePage;  
  begin  
    if FActivePage <> nil then  
      FActivePage.Visible := False;  
    FActivePage := APage;  
  end;  

  procedure DoMakeVisibleActivePage;  
  begin  
    if FActivePage <> nil then  
    begin  
      FActivePage.BringToFront;  
      FActivePage.Visible := True;  
      FActivePage.Invalidate;  
    end;  
  end;  

  function DoFindActiveControl(AParentForm: TCustomForm): TWinControl;  
  begin  
    if (APage <> nil) and (AParentForm <> nil) and (FActivePage <> nil) and  
      (AParentForm.ActiveControl = FActivePage) then  
    begin  
      if APage.Enabled and Control.Visible and Control.Enabled and Control.Parent.CanFocus then  
        Result := APage  
      else  
        Result := Control;  
    end  
    else  
      Result := nil;  
  end;  

  procedure DoSetActiveControl(AParentForm: TCustomForm; AActiveControl: TWinControl);  
  begin  
    if AActiveControl <> nil then  
      AParentForm.ActiveControl := AActiveControl;  
    if (AParentForm <> nil) and (FActivePage <> nil) and (AParentForm.ActiveControl = FActivePage) then  
      FActivePage.SelectFirst;  
  end;  

  procedure SynchronizeTabIndex;  
  begin  
    if ActivePage = APage then  
    begin  
      BeginUpdate;  
      FActivePageSetting := True;  
      try  
        if (APage <> nil) and APage.TabVisible then  
          TabIndex := APage.FTab.Index  
        else  
          TabIndex := -1;  
      finally  
        FActivePageSetting := False;  
        EndUpdate;  
      end;  
    end;  
  end;  

var  
  ANewActiveControl: TWinControl;  
  AParentForm: TCustomForm;  
  AModified: Boolean;  
begin  
  if FActivePage <> APage then  
  begin  
    if not CanChangeActivePage(APage) then  
      Exit;  

    LockNotifyEvents(True);  
    try  
      AParentForm := GetParentForm(Control);  
      if (AParentForm <> nil) and (FActivePage <> nil) and  
        FActivePage.ContainsControl(AParentForm.ActiveControl) then  
      begin  
        AParentForm.ActiveControl := FActivePage;  
        if AParentForm.ActiveControl <> FActivePage then  
        begin  
          TabIndex := FActivePage.FTab.Index;  
          Exit;  
        end;  
      end;  

      ANewActiveControl := DoFindActiveControl(AParentForm);  
      DoChangeActivePage;  
      DoMakeVisibleActivePage;  
      DoSetActiveControl(AParentForm, ANewActiveControl);  
    finally  
      LockNotifyEvents(False);  
    end;  

    AModified := True;  
  end  
  else  
    AModified := False;  
  SynchronizeTabIndex;  
  if AModified then  
  begin  
    DoPageChange;  
    Control.SetModified;  
  end;  
end;  

It works like a charm!
Thank you for your fast answer.

Great news! Thanks.